;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; BANLISTEXEC ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;info:
;
;  by wiebe @ QuakeNet
;  version 1.0     (written and tested on mIRC 6.14)
;
;  last edit: Tue Feb 17 2004
;
;
;What does this script do?
;
;  retrieves the banlist from a channel
;  and sends the info the an alias, example:
; 
;
;How to use this script?
;
;  /banlistexec <channel> <alias> [params]
;    to request the banlist from channel and send the info to the alias
;
;  /banlistexec -c
;   to clear the queue
;
;   the script sends the following things to the alias:
;
;   367 <channel> <banmask> <nick> <ctime>
;     channel, from which the ban info is
;     banmask, the ban that is set
;     nick, who set the ban
;     ctime, when the ban was set
;
;   368 <channel> End of Channel Ban List
;     this marks the end of the banlist
; 
;  WARNING: DO NOT USE HALT IN AN ALIAS, USE RETURN!
;   halt also halts the calling alias/event, return only stops the current alias
;   and gives control back to the calling alias/event
;   using halt in alias'es that are called from this script can cause it not to work 100%
;
;  example at end of script
;
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ALIAS BANLISTEXEC.DELAY ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
alias -l banlistexec.delay {
  ; what delay in seconds should banlistexec have when it is called
  !return 1
}

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ALIAS BANLISTEXEC.RESTART ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
alias -l banlistexec.restart {
  ; what delay in seconds should be between multiple ban requests
  !return 5
}

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; stop here, only change stuff if you know what you are doing
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ALIAS BANLISTEXEC ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; /banlistexec <chan> <alias> <params..>
alias banlistexec {

  ; we are connected
  if ($status == connected) {

    ; '$1' is '-c'
    if ($1 == -c) {

      ; clear the queue
      $banlistexec.queue($+(ban.exec.queue.,$cid)).clear

      ; stop
      !return
    }

    ; less then 3 parameters, stop
    if ($0 < 3) { return }

    ; check if IBL has the bans
    if ($chan($1).ibl == $true) {

      ; set a var
      !var %x = $ibl($1,0)

      ; loop as long as '%x' is greater then 0
      while (%x) {

        ; run the alias with the requested info
        $2- 367 $1 $ibl($1,%x) $ibl($1,%x).by $ibl($1,%x).ctime

        ; decrease var
        !dec %x
      }

      ; send end of channel ban list
      $2- 368 $1 End of Channel Ban List

      ; stop, no need to request the banlist
      !return
    }

    ; if there is a , in '$1' we take the first part only
    ; replace some chars in '$1', see in the alias itself why
    !tokenize 32 $banlistexec.lower($gettok($1,1,44)) $1-

    ; add queue '$1-' to the queue
    banlistexec.queue $+(ban.exec.queue.,$cid) $1-

    ; check if '$1-' is not already in the hash table
    if (!$hfind($+(ban.exec.queue.,$cid,.item),$1-,0).data) {

      ; increase item 'last' in the hash table
      !hinc -m $+(ban.exec.queue.,$cid,.item) last

      ; add an item with the value 'last' has with value '$1-'
      !hadd -m $+(ban.exec.queue.,$cid,.item) $hget($+(ban.exec.queue.,$cid,.item),last) $1-
    }

    ; check if the timer does not already run
    if (!$timer($+($cid,.banlistexec))) {

      ; start a timer
      .!timer $+ $cid $+ .banlistexec 1 $$banlistexec.delay banlistexec.dump
    }
  }
}

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ALIAS BANLISTEXEC.DUMP ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
alias -l banlistexec.dump {

  ; set the next item
  !var %chan = $gettok($banlistexec.queue($+(ban.exec.queue.,$cid)).next,1,32)

  ; '%chan' is something and left char is in '$chantypes'
  if (%chan) && ($left(%chan,1) isin $chantypes) {

    ; enable the '#banlistexec' group
    .!enable #banlistexec

    ; send ban
    .!quote MODE %chan +b
  }

  ; there are items left in the queue
  if ($banlistexec.queue($+(ban.exec.queue.,$cid)).size > 0) {

    ; start a timer to start this alias again
    .!timer $+ $cid $+ .banlistexec 1 $$banlistexec.restart banlistexec.dump
  }
}

; start of '#banlistexec' group
#banlistexec off

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; RAW 367 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; raw 367 <you> <channel> <ban> <nick> <time>
raw 367:*:{

  ; check that nick '$2' is in the hash table
  if ($hfind($+(ban.exec.queue.,$cid,.item),$banlistexec.lower($2) *,0,w).data > 0) {

    ; set a var
    !var %x = $hfind($+(ban.exec.queue.,$cid,.item),$banlistexec.lower($2) *,0,w).data

    ; loop as long as '%x' is greater then 0
    while (%x) {

      ; set a var
      !var %t = $gettok($hget($+(ban.exec.queue.,$cid,.item),$hfind($+(ban.exec.queue.,$cid,.item),$banlistexec.lower($2) *,%x,w).data),2-,32)

      ; send info to alias
      $gettok(%t,2-,32) $numeric $gettok(%t,1,32) $3-

      ; decrease '%x'
      !dec %x
    }

    ; stop mirc from showing this raw
    !haltdef
  }
}

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; RAW 368 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; raw 368 <you> <channel> :End of Channel Ban List.
raw 368:*: {

  ; check if the hash table exists
  if ($hget($+(ban.exec.queue.,$cid,.item))) {

    ; while
    while ($hfind($+(ban.exec.queue.,$cid,.item),$banlistexec.lower($2) *,1,w).data) {

      ; set a var
      !var %t = $gettok($hget($+(ban.exec.queue.,$cid,.item),$hfind($+(ban.exec.queue.,$cid,.item),$banlistexec.lower($2) *,1,w).data),2-,32)

      ; send info to alias
      $gettok(%t,2-,32) $numeric $gettok(%t,1,32) $3-

      ; delete the item from the hash table
      !hdel $+(ban.exec.queue.,$cid,.item) $hfind($+(ban.exec.queue.,$cid,.item),$banlistexec.lower($2) *,1,w).data

    }

    ; disable the '#banlistexec' group
    banlistexec.disable

    ; stop mirc from showing this raw
    !haltdef
  }
}

; end of '#banlistexec' group
#banlistexec end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ALIAS BANLISTEXEC.LOWER ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; $banlistexec.lower(chan)
alias -l banlistexec.lower {

  ; on IRC these chars are upper(lower) case of eachother: { = [, } = ], | = \, ~ = ^
  ; so here we replace them to make sure we compare the right things right
  !return $replace($1,$chr(123),$chr(91),$chr(125),$chr(93),$chr(124),$chr(92),$chr(126),$chr(94))
}

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ALIAS BANLISTEXEC.DISABLE ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; this alias will only disable the group '#banlistexec' if it is nolonger needed (checks all connections)
alias -l banlistexec.disable {

  ; set a var
  !var %x = 1

  ; loop through all connection id's
  while (%x <= $scid(0)) {

    ; there is 1 item in the 'item' queue
    if ($hget($+(banlist.exec.queue.,$scid(%x),.item),0).item == 1) {

      ; free the hash table
      !hfree $+(banlist.exec.queue.,$scid(%x),.item)
    }

    ; more then 1 item in the 'item' queue
    elseif ($hget($+(banlist.exec.queue.,$scid(%x),.item),0).item > 1) {

      ; stop
      !return
    }

    ; increase '%x' and go on to the next connection id
    !inc %x
  }

  ; disable the '#banlistexec' group
  .!disable #banlistexec
}


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ALIAS BANLISTEXEC.QUEUE ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; $1 = table, $2- = thing
alias banlistexec.queue {

  ; there is a 2nd parameter and mode '$2-' is not already in the queue
  if ($2 != $null) && ((!$hfind($1,$2-)) || ($hfind($1,$2-).data == 0)) {

    ; increase item 'last'
    !hinc -m $1 last

    ; add mode '$2-' to the hashtable with item name that 'last' has
    !hadd -m $1 $hget($1,last) $2-
  }

  ; called as identifier ($alias) and propertie is next ($alias().next) and hash table '$1' exists
  elseif ($isid) && ($prop == next) && ($hget($1)) {

    ; increase item 'first'
    !hinc -m $1 first

    ; 'first' is smaller or equal to 'last'
    if ($hget($1,first) <= $hget($1,last)) {

      ; store next item in var '%next'
      !var %next = $hget($1,$hget($1,first))

      ; delete this item from the hashtable
      !hdel $1 $hget($1,first)

      ; this is the last item
      if ($hget($1,first) >= $hget($1,last)) {

        ; free the hash table
        !hfree $1
      }

      ; return '%next'
      !return %next
    }
  }

  ; called as identifier ($alias) and propertie is size ($alias().size)
  elseif ($isid) && ($prop == size) {

    ; decrease number of items with 1, (1 item in queue, and last is there)
    !return $iif($calc($hget($1,0).item -1) >= 0,$ifmatch,0)
  }

  ; called as identifier ($alias) and propertie is clear ($alias().clear)
  elseif ($isid) && ($prop == clear) {

    ; free hashtables that match $1
    !hfree -w $1
  }
}

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; DISCONNECT EVENT ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
on *:disconnect: {

  ; check if the 'item' hash table exist
  if ($hget($+(ban.exec.queue.,$cid,.item))) {

    ; free the hash table
    !hfree $+(ban.exec.queue.,$cid,.item)
  }

  ; clear the queue
  $banlistexec.queue($+(ban.exec.queue.,$cid)).clear

  ; disable the '#banlistexec' group
  banlistexec.disable
}






; example script
; /copybanlist #from #to
alias copybanlist {
  if ($me isop $2) && ($left($1,1) isin $chantypes) {
    banlistexec $1 copybanlist.ban $2
  }
}

; <chan to> <chan from> <banmask>
alias -l copybanlist.ban {
  if ($3- == End of Channel Ban List) {
    !echo -a done
  }
  elseif ($me isop $1) {
    !mode $1 +b $3
  }
}